BEREGNING AV FORSKUDDSTREKK INNTEKTSÅRET 2014. Desember 2013. Skatteetatens IT- og Servicepartner

BEREGNING AV FORSKUDDSTREKK INNTEKTSÅRET 2014 Desember 2013 Skatteetatens IT- og Servicepartner

ii

FORORD Vedlagt følger dokumentasjon og subprogram i COBOL for beregning av forskuddstrekk for inntektsåret 2014. Hensikten med dokumentet er å vise hvordan en kan beregne trekkbeløpets størrelse for en lønnsmottaker eller pensjonist med tabelltrekk, slik at et oppslag i den aktuelle trekktabellen ikke er nødvendig. Programmeringen bygger på skatteregler for 2014 etter Stortingets vedtak. iii

Innholdsfortegnelse 1. INNLEDNING... 1 2. INPUT TIL PROGRAMMET... 2 3. BESKRIVELSE AV PROGRAMMET... 6 4. PROGRAMMET... 14 iv

1. INNLEDNING Dokumentasjonen og subprogrammet stilles vederlagsfritt til disposisjon for alle som i offentlige eller private virksomheter benytter elektroniske lønnsrutiner. Ingen form for kopiering, overdragelse eller salg er tillatt uten godkjennelse fra Skattedirektoratet. Ajourføring av programmet utføres av Skattetatens IT- og Servicepartner (SITS), og forespørsler angående dokumentasjon eller program rettes til SITS på mail til forskudd@skatteetaten.no. Dette dokumentet tilgjengeliggjøres for publikum kun via våre hjemmesider (skatteetaten.no/arbeidsgiver), og man vil her også kunne finne samtlige trekktabeller lagt ut i tekstformat. Vi har her også en tjeneste som heter Tabelltrekk for skattekort, hvor man kan legge inn tabellnummer og trekkgrunnlag og få ut trekket. 1 I COBOL-programmet er alle endringer i forhold til fjoråret markert med en strek i margen ( ). Dette gjelder både skattemessige endringer og generelle forbedringer av programmet. Der hvor en eller flere kodelinjer er fjernet, vil det stå en strek foran en blank linje. Vi gjør oppmerksom på at skattytere i Finnmark og Nord-Troms med såkalt finnmarksfradrag og lavere fellesskatt og toppskatt, som vanlig har fått et ekstra tabellfradrag (dvs. "snillere" tabell). Dette betyr at det ikke må legges inn egne satser og fradrag for disse i programmet! 2 Dette er ikke noen endring fra i fjor. Det er i år flere endringer enn normalt i programmet i forhold til fjorårsversjonen. I tillegg til normale endringer på grunn av endringer i skattesatsene for 2014, er dette det viktigste som er endret i programmet fra 2013: - For en del av trekkperiodene, særlig dagtabellene, ga trekkrutinen et feil resultat på høye trekkgrunnlag og bruk av de såkalte overskytende prosentene. Dette er rettet opp ved at programmet beregner trekket på mye høyere trekkgrunnlag enn tidligere. Dette gjør også at man nå kun har behov for en overskytende prosent. - Vi har også ønsket å standardisere trinnene i tabellene mellom de forskjellige tabelltypene. Dette betyr at nå vil alle månedstabeller ha inntektssprang på kr 100, alle 14-dagers-tabeller på kr 50, og alle uke- og dagtabeller på kr 20. I praksis betyr disse endringene at en god del kode er fjernet fra programmet. 1 Dette er tilgjengelig fra 17. desember 2013 2 Dette gjelder ikke for de spesielle tabellene 6300-6800. Disse benytter Finnmarkssatser. Beregning av forskuddstrekk 1

2. INPUT TIL PROGRAMMET Følgende data forutsettes innlest for hver trekkberegning: PARM-TREKK-GRLAG, PARM-TAB-TREKK-PERIODE, PARM-PENSJONIST, PARM-TABELLNR Disse flyttes så over i Working-Storage til feltene WS-TREKK-GRLAG, WS-TAB-TREKK-PERIODE, WS-PENSJONIST, WS-TABELLNR WS-TREKK-GRLAG trekkgrunnlaget; den del av inntekten for den aktuelle inntektsperioden som legges til grunn for beregning av forskuddstrekk. Beløp i hele kroner. WS-TAB-TREKK-PERIODE den tabelltrekkperiode som ønskes anvendt ved forskuddstrekk. Feltet kan ha en verdi fra og med 1 til og med 7. Sjø-tabellene kan bare ha verdien 1, 2 eller 3. Betydningen av WS-TAB-TREKK-PERIODE er som følger: WS-TAB-TREKK- PERIODE Tabell 1 Måned 2 14-dager 3 Uke 4 4-dager 5 3-dager 6 2-dager 7 Dag WS-PENSJONIST pensjonskode. Denne koden er kun aktuell ved de ordinære trekktabellene, og kan ha verdien 'P' eller blank. 'P' betegner at det skal benyttes lav sats for trygdeavgift, lavere nedre grense for minstefradrag og at antall inntekts- og trekkperioder avviker fra de "vanlige" tabellene. Beregning av forskuddstrekk 2

WS-TABELLNR tabellnummer. Flyttes også til hjelpe-feltet WS-TABELL- NUMMER som er delt opp i feltene WS-SKATTE-PROSENT (første posisjon), WS-TABELL-TYPE (andre posisjon) og WS- TABELL-NR (tredje og fjerde posisjon). WS-SKATTE-PROSENT betegnet opprinnelig summen av den aktuelle kommunale og fylkeskommunale skatteprosent, men siden denne nå er lik for samtlige trekktabeller, benyttes ikke denne lenger til å sette det skattøre (SKATTORE) som skal benyttes. WS-TABELL-TYPE betegner for de ordinære trekk-tabellene, sjø-tabellene og tabellene for utenlandske pendlere den aktuelle skatteklasse (1 eller 2). For standardfradrag-tabellene angir ikke WS-TABELL-TYPE skatteklassen direkte. Hvis WS-TABELL-TYPE = 3, 5 eller 7 betyr dette at satsene for klasse 1 skal benyttes, mens WS- TABELL-TYPE = 4, 6 eller 8 betyr at satsene for klasse 2 skal benyttes. WS-TABELL-NR betegner for de ordinære trekk-tabellene det fradrag/tillegg i inntekten (FRADRAG) man skal ta hensyn til ved beregning av forskuddstrekk; gitt i tabellen på neste side. For WS-TABELL-NR mindre enn 20 gis det fradrag, mens for WS-TABELL-NR større enn 19 gis det tillegg. Beregning av forskuddstrekk 3

WS-TABELL-NR FRADRAG 00 0 01 4000 02 8000 03 12000 04 16000 05 20000 06 24000 07 28000 08 32000 09 36000 10 41000 11 46000 12 53000 13 60000 14 70000 15 80000 16 90000 17 100000 18 110000 19 120000 20-4000 21-8000 22-12000 23-16000 24-20000 25-24000 26-28000 27-32000 28-36000 29-41000 30-46000 31-53000 32-60000 33-67000 Beregning av forskuddstrekk 4

For standardfradrag-tabellene, sjø-tabellene og tabellene for utenlandske pendlere har WS-TABELLNR (4-siffer) følgende betydning: WS- TABELLNR KLASSE TRYGDE- AVGIFT ANTALL TREKK- PERIODER(MND) 7300 1 HØY 10,5 7350 1 HØY 12 7400 2 HØY 10,5 7450 2 HØY 12 7500 1 NEI 12 7550 1 NEI 10,5 7600 2 NEI 12 7650 2 NEI 10,5 7700 1 LAV 12 7800 2 LAV 12 0100 1 NEI 12 0101 1 HØY 12 0200 2 NEI 12 0201 2 HØY 12 7150 1 HØY 12 7160 1 NEI 12 7170 1 NEI 10,5 7250 2 HØY 12 7260 2 NEI 12 7270 2 NEI 10,5 For standardfradragtabellene med finnmarkssatser (6300 6800) har WS-TABELLNR samme betydning som de tilhørende vanlige standardfradragtabellene. Beregning av forskuddstrekk 5

3.BESKRIVELSE AV PROGRAMMET A-INITIALISER SECTION Hver gang subprogrammet blir kalt opp, må en del felter nullstilles, slik at disse ikke inneholder verdier fra forrige kall. Leser inn fra Linkage Section til Working Storage Section (oppkallingskriteriene). Aktuelle felter initialiseres. Beregner antall trekkperioder for de forskjellige tabellene for 4, 3, 2, og 1 dag. Dette gjøres slik i disse tilfellene fordi det ikke er en fast verdi som for de andre tabellene, men en formel. Bestemmer tabelltype. Dataelementet TABELLTYPE gis en tilstand, som kan være: 1 = VANLIG (ordinær trekk-tabell) 2 = PENSJONIST (pensjonist-tabell) 3 = STANDARD-FRADRAG (standardfradrag-tabell) 4 = SJO (sjø-tabell) Setter klassefradrag og prosentsatser for fellesskatt og toppskatt. Dette gjøres ut fra første siffer i tabellnummeret. 6 gir finnmarkssatser. Bestemmer tabelltrekkperiode. Dataelementet TAB-TREKK-PERIODE gis en tilstand, som kan være: 1 = MAANED (måneds-tabell) 2 = 14-DAGER (14-dagers-tabell) 3 = UKE (uke-tabell) 4 = 4-DAGER (4-dagers tabell) 5 = 3-DAGER (3-dagers tabell) 6 = 2-DAGER (2-dagers tabell) 7 = 1-DAG (1-dags tabell) A-STYRE SECTION Denne seksjonen styrer flyten i programmet. Det settes verdier i de forskjellige tabellene i den seksjonen av B-SETT-VERDIER som tilhører den aktuelle tabelltype. Deretter avrundes trekkgrunnlaget i seksjon av B-AVRUNDING. Til slutt beregnes fradrag og skattbar inntekt i B-BEREGN-FRADRAG, kommuneog fellesskatt i B-BEREGN-NETTOSKATT, trygdeavgift i B-BEREGN- TRYGDEAVGIFT, toppskatt i B-BEREGN-TOPPSKATT og forskuddstrekk i B-BEREGN-TREKK. Beregning av forskuddstrekk 6

B-SETT-VERDIER-VANLIG SECTION Dataelementet KLASSE gis en tilstand ut fra tabelltype. Det settes maksimalt trekkgrunnlag (MAX-TREKK-GRUNNLAG), antall inntekts-perioder (ANT-INNTEKTS-PERIODER) og antall trekk-perioder (ANT- TREKK-PERIODER). Det må tas spesielle hensyn til tabellene 7150 7270, da disse har spesielle trekkog inntektsperioder og beløpsgrenser for når overskytende prosent skal benyttes. B-SETT-VERDIER-PENSJONIST SECTION Dataelementet KLASSE gis en tilstand ut fra tabelltype. Det settes maksimalt trekkgrunnlag (MAX-TREKK-GRUNNLAG), antall inntekts-perioder (ANT-INNTEKTS-PERIODER) og antall trekk-perioder (ANT- TREKK-PERIODER). B-SETT-VERDIER-STFRADRAG SECTION Dataelementet KLASSE gis en tilstand ut fra tabelltype. Det settes maksimalt trekkgrunnlag (MAX-TREKK-GRUNNLAG) og antall inntekts-perioder (ANT-INNTEKTS-PERIODER). Antall trekk-perioder (ANT- TREKK-PERIODER) settes ut fra type standardfradrag-tabell (tabellnummer), slik at det for enkelte tabellnummere brukes de verdier som ligger i ANT-INNT- PERIODER-STFRADRAG, mens for resten av standardfradrag-tabellene brukes det de verdier som ligger i ANT-TRK-PERIODER-STFRADRAG. B-SETT-VERDIER-SJO SECTION Dataelementet KLASSE gis en tilstand ut fra tabelltype. Det settes maksimalt trekkgrunnlag (MAX-TREKK-GRUNNLAG), antall inntekts-perioder (ANT-INNTEKTS-PERIODER) og antall trekk-perioder (ANT- TREKK-PERIODER). B-AVRUNDING SECTION Avrunder trekkgrunnlaget ut fra perioden det skal beregnes forskuddstrekk for, på grunnlag av avrundingsregler gjengitt i tabellen under: WS-TAB-TREKK- PERIODE 1 Avrundingsregler WS-TREKK-GRLAG avrundes nedover til det største heltall som er delelig med 100. Derpå legges det til 50. 2 WS-TREKK-GRLAG avrundes nedover til det største heltall som er delelig med 50. Derpå legges det til 25. > 2 WS-TREKK-GRLAG avrundes nedover til det største heltall som er delelig med 20. Derpå legges det til 10. Beregning av forskuddstrekk 7

I tillegg blir feltet WS-TRGRL-AVRUNDET beregnet. Når WS-TREKK-GRLAG er avrundet som angitt, gjelder så for den totale årsinntekten: AARS-INNTEKT = WS-TREKK-GRLAG * ANT-INNTEKTS-PERIODER uansett hvilket nummer den aktuelle trekktabellen har. B-BEREGN-OVERSKYTENDE-TREKK SECTION Utføres bare hvis trekkgrunnlaget overstiger det maksimale trekkgrunnlaget for tabellen (MAX-TRK-GRLAG). Tabell-nummer 7100-7133 7200-7233 7100P-7133P 7200P-7233P 7300 7400 7350 7450 7500 7600 7550 7650 7700 7800 0100 0200 0101 0201 6300 6400 6350 6450 6500 6600 6550 6650 6700 6800 OVERSKYTENDE- PROSENT 54 48 54 47 39 45 44 39 47 50 44 36 41 41 Beregning av forskuddstrekk 8

Tabell-nummer 7150 7250 7160 7260 7170 7270 OVERSKYTENDE- PROSENT 47 39 45 Etter at grunnlaget er avrundet beregnes det overskytende trekket gitt ved en av formelen under. OVERSKYTENDE-TREKK = (WS-TREKK-GRLAG MAX-TREKK-GRUNNLAG) * OVERSKYTENDE-PROSENT B-BEREGN-FRADRAG SECTION Her beregnes forskjellige fradrag, avhengig av tabelltype. Anvendt minstefradrag - ordinære- og standardfradrag-tabeller Her benyttes enten minstefradrag eller lønnsfradrag, etter hva som er mest lønnsomt for skattyteren. Først beregnes det anvendte minstefradraget på følgende måte: ANV-MINSTE-FRADRAG = (AARS-INNTEKT * ANV-MINSTE-FRAD-PROSENT) / 100 men hvis ANV-MINSTE-FRADRAG beregnet etter denne formelen blir større enn MAX-ANV-MINSTE-FRADRAG, settes ANV-MINSTE-FRADRAG = MAX-ANV-MINSTE-FRADRAG eller hvis ANV-MINSTE-FRADRAG beregnet etter denne formelen blir mindre enn MIN-ANV-MINSTE-FRADRAG, settes ANV-MINSTE-FRADRAG = MIN-ANV-MINSTE-FRADRAG Deretter settes lønnsfradraget på følgende måte: Hvis AARS-INNTEKT er mindre enn ANV-LONNSFRADRAG settes WS-LONNSFRADRAG = AARS-INNTEKT eller hvis AARS-INNTEKT er større enn ANV-LONNSFRADRAG settes WS-LONNSFRADRAG = ANV-LONNSFRADRAG Beregning av forskuddstrekk 9

Så settes minstefradraget lik lønnsfradraget hvis det er større enn minstefradraget, det gjøres på følgende måte: Hvis WS-LONNSFRADRAG er større enn ANV-MINSTE-FRADRAG settes ANV-MINSTE-FRADRAG = WS-LONNSFRADRAG Hvis derimot AARS-INNTEKT er mindre enn ANV-MINSTE-FRADRAG settes ANV-MINSTE-FRADRAG = AARS-INNTEKT Minstefradrag pensjonist tabeller Dette beregnes på samme måte som de ordinære tabellene, men det benyttes egne satser og beløpsgrenser i pensjonist-tabellene. Lønnsfradrag benyttes heller ikke for disse tabellene. Minstefradrag - sjøtabeller Dette beregnes på samme måte som de ordinære tabellene, men det benyttes enten virkelig minstefradrag eller virkelig lønnsfradrag (etter hva som er mest lønnsomt for skattyteren). Fradrag/tillegg i inntekten Beregnes kun for ordinære og pensjonist-tabeller, og bestemmes av WS-TABELL-NR som er de 2 siste sifrene i tabell-nummeret. Standardfradrag- og sjø-tabellene har ikke slikt fradrag. Standardfradrag Beregnes kun for standardfradrag- og sjø-tabeller, etter formelen: ST-FRADRAG = (AARS-INNTEKT * STFRADRAG-PROSENT) * 100 Begrenses oppad til maksimumsbeløpet : IF ST-FRADRAG > MAX-STFRADRAG MOVE MAX-STFRADRAG TO ST-FRADRAG Sjømanns-fradrag Beregnes kun for sjø-tabellene etter gitt prosentsats og maksimums-beløp. SJO-FRADRAG = (AARS-INNTEKT * SJO-PROSENT) / 100 men hvis SJO-FRADRAG beregnet etter denne formelen blir større enn MAX-SJO-FRADRAG, settes SJO-FRADRAG = MAX-SJO-FRADRAG Beregning av forskuddstrekk 10

Klassefradrag settes slik: KLASSE-FRADRAG = WS-KLASSE-FRADRAG(KLASSE) Skattbar inntekt Beregner den delen av inntekten som det skal trekkes skatt av, etter formelen: SKATTBAR-INNTEKT = AARS-INNTEKT - ANV-MINSTE-FRADRAG - MINSTE-FRADRAG - FRADRAG - ST-FRADRAG - SJO-FRADRAG - KLASSE-FRADRAG B-BEREGN-NETTOSKATT SECTION Merk at hvis SKATTBAR-INNTEKT er negativ, beregnes det ikke kommune- og fellesskatt, og programmet går direkte til paragrafen B-BEREGN-NETTOSKATT-SLUTT. Kommune-skatt beregnes etter formelen: KOMMUNE-SKATT = (SKATTBAR-INNTEKT * SKATTORE) / 100 Felles-skatt beregnes etter formelen: FELLES-SKATT = (SKATTBAR-INNTEKT * FELLES-SKATT-PROSENT) / 100 B-BEREGN-TRYGDEAVGIFT SECTION Trygdeavgift beregnes etter følgende regler: Det skal ikke beregnes trygdeavgift for: Tabellnummer 7500, 7550, 7600, 7650, 0100, 0200, 6500, 6550, 6600, 6650, 7160, 7170, 7260, 7270 eller AARS-INNTEKT er mindre enn AVG-FRI-TRYGDEAVGIFT Det skal beregnes lav trygdeavgift for: Tabellnummer 7700, 7800, 6700, 6800 eller for pensjonister Beregning av forskuddstrekk 11

Hvis AARS-INNTEKT er større enn LAV-GRENSE-TRYGDEAVGIFT gjelder formelen TRYGDE-AVGIFT = (AARS-INNTEKT * LAV-TRYGDEAVG-PROSENT) / 100 ellers gjelder TRYGDE-AVGIFT = (AARS-INNTEKT - AVG-FRI-TRYGDEAVGIFT) * TRYGDE-PROSENT / 100 For de øvrige tabellnummer skal det beregnes høy trygdeavgift : Hvis AARS-INNTEKT er større enn HOY-GRENSE-TRYGDEAVGIFT gjelder formelen TRYGDE-AVGIFT = (AARS-INNTEKT * HOY-TRYGDEAVG-PROSENT) / 100 ellers gjelder TRYGDE-AVGIFT = (AARS-INNTEKT - AVG-FRI-TRYGDEAVGIFT) * TRYGDE-PROSENT / 100 B-BEREGN-TOPPSKATT SECTION TABELL-TOPPSKATT-PROSENT, TOPPSKATT-LAV-GRENSE og TABELL-TOPPSKATT-HOY-GRENSE. Først beregnes det toppskatt på første intervall. Elementet KLASSE1 viser til klasse 1, og KLASSE2 til klasse 2. Hvis AARS-INNTEKTEN ligger i intervallet mellom TOPPSKATT-LAV og TOPPSKATT-HOY gjelder formelen TOPP-SKATT-TRINN1 = (AARS-INNTEKT - TOPPSKATT-LAV(KLASSE) * TOPPSKATT-PROSENT(1) / 100 Når denne testen har slått til, betyr det at det ikke er mer toppskatt å beregne (det vil si at inntekten er lavere enn grensen for toppskatt på det neste intervallet). Hvis derimot neste test slår til, skal det først beregnes toppskatt for den delen av inntekten som ligger i det første intervallet, og deretter for resten av inntekten i det andre intervallet. Dette gjøres på følgende måte: Hvis AARS-INNTEKTEN er større enn både TOPPSKATT-LAV og TOPPSKATT-HOY gjelder formelen TOPP-SKATT-TRINN1 = Beregning av forskuddstrekk 12

(TOPPSKATT-HOY(KLASSE) - TOPPSKATT-LAV(KLASSE)) * TOPPSKATT-PROSENT(1) / 100 For de tilfeller hvor den foregående testen har slått til vil det altså bli beregnet toppskatt også på det andre trinnet. Hvis AARS-INNTEKTEN er større enn TOPPSKATT-HOY gjelder TOPP-SKATT-TRINN2 = (AARS-INNTEKT - TOPPSKATT-HOY(KLASSE)) * TOPPSKATT-PROSENT(2) / 100 Til slutt beregnes så den endelige toppskatten, altså summen av toppskatten i det første trinnet og det andre trinnet, etter formelen: SUM-TOPP-SKATT = TOPP-SKATT-TRINN1 + TOPP-SKATT-TRINN2 B-BEREGN-TREKK SECTION Her beregnes det endelige forskuddstrekket ut fra formelen: SUM-TREKK = KOMMUNE-SKATT + FELLES-SKATT + TRYGDE-AVGIFT + SUM-TOPP-SKATT Siden man i hele programmet har beregnet ut fra hele år, deles trekket til slutt opp i forhold til den aktuelle trekkperioden. Trekket blir avrundet, (unntatt for sjø-tabellene) og skulle det bli negativt, settes det lik 0. TREKK ROUNDED = (SUM-TREKK / ANT-TREKK-PERIODER) For enkelte tabellnummere vil det på lave trekkgrunnlag kunne forekomme at trekket blir høyere enn grunnlaget. I disse tilfellene settes trekket lik trekkgrunnlaget. Deretter plusser man på det eventuelle overskytende trekket som er beregnet. Beregning av forskuddstrekk 13

4 PROGRAMMET IDENTIFICATION DIVISION. PROGRAM-ID. FT4P200T. AUTHOR. PER J. RISTUN. DATE-WRITTEN. NOVEMBER 1993 **---------------------------------------------------------------- * BESKRIVELSE : PROGRAMMET BEREGNER FORSKUDDSTREKK FOR ÅR 2014 * * DET ER GJORT ENDEL ENDRINGER/FORENKLINGER I * PROGRAMMET I FORHOLD TIL 2013-VERSJONEN. * DISSE GÅR I HOVEDSAK UT PÅ AT MAN HAR FORSØKT Å * STANDARDISERE INNTEKTSSPRANG, AVRUNDING, OG MAKS-BELØP * FOR DE FORSKJELLIGE TABELL-TYPENE. * **---------------------------------------------------------------- ENVIRONMENT DIVISION. CONFIGURATION SECTION. SPECIAL-NAMES. DECIMAL-POINT IS COMMA. DATA DIVISION. FILE SECTION. WORKING-STORAGE SECTION. 01 SLUTT-BRYTER-PARAMETER PIC 9 VALUE 0. 88 SLUTT-PAA-PARAMETER VALUE 1. 01 TABELLTYPE PIC 9 VALUE 0. 88 VANLIG VALUE 1. 88 PENSJONIST VALUE 2. 88 STANDARD-FRADRAG VALUE 3. 88 SJO VALUE 4. 01 KLASSE PIC 9 VALUE 0. 88 KLASSE1 VALUE 1. 88 KLASSE2 VALUE 2. 01 TAB-TREKK-PERIODE PIC 9 VALUE 0. 88 MAANED VALUE 1. 88 14-DAGER VALUE 2. 88 UKE VALUE 3. 88 4-DAGER VALUE 4. 88 3-DAGER VALUE 5. 88 2-DAGER VALUE 6. 88 1-DAG VALUE 7. Beregning av forskuddstrekk 14

* TABELLER FOR MAX TREKKGRUNNLAG * ANTALL INNTEKTS-PERIODER * ANTALL TREKK-PERIODER * FOR HVER TABELLTYPE 01 TABELLER. * FOR ALLE TABELLER * MAX TREKKGRUNNLAG SOM KAN AVLESES I TABELLEN. FOR STØRRE BELØP * MÅ DET UTREGNES MED EN VISS PROSENTSATS. 02 TABELL-TRKGRLAG. 05 FILLER PIC 9(7) VALUE 79800. 05 FILLER PIC 9(7) VALUE 36800. 05 FILLER PIC 9(7) VALUE 18400. 05 FILLER PIC 9(7) VALUE 15900. 05 FILLER PIC 9(7) VALUE 11900. 05 FILLER PIC 9(7) VALUE 7900. 05 FILLER PIC 9(7) VALUE 3900. 02 MAX-TRK-GRLAG REDEFINES TABELL-TRKGRLAG OCCURS 7 TIMES PIC 9(7). * VANLIGE TABELLER * ANTALL INNTEKTSPERIODER 02 TABELL-INNTPERIODER-VANLIG. 05 FILLER PIC 999V99 VALUE 12,12. 05 FILLER PIC 999V99 VALUE 26,26. 05 FILLER PIC 999V99 VALUE 52,52. 05 FILLER PIC 999V99 VALUE 60,60. 05 FILLER PIC 999V99 VALUE 80,80. 05 FILLER PIC 999V99 VALUE 121,20. 05 FILLER PIC 999V99 VALUE 242,40. 02 ANT-INNT-PERIODER-VANLIG REDEFINES TABELL-INNTPERIODER-VANLIG OCCURS 7 TIMES PIC 999V99. * VANLIGE TABELLER * ANTALL TREKKPERIODER * ANTALL TREKKPERIODER FOR 4, 3, 2 OG 1 DAG BLIR BEREGNET I * A-INITIALISER SECTION. 02 TABELL-TREKKPERIODER-VANLIG. 05 FILLER PIC 999V9(7) VALUE 10,5. 05 FILLER PIC 999V9(7) VALUE 23,0. 05 FILLER PIC 999V9(7) VALUE 46,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 02 ANT-TRK-PERIODER-VANLIG REDEFINES TABELL-TREKKPERIODER-VANLIG OCCURS 7 TIMES PIC 999V9(7). Beregning av forskuddstrekk 15

* PENSJONIST-TABELLER * ANTALL INNTEKTSPERIODER 02 TABELL-INNTPERIODER-PENSJONIST. 05 FILLER PIC 999V99 VALUE 12. 05 FILLER PIC 999V99 VALUE 26. 05 FILLER PIC 999V99 VALUE 52. 05 FILLER PIC 999V99 VALUE 91. 05 FILLER PIC 999V99 VALUE 122. 05 FILLER PIC 999V99 VALUE 183. 05 FILLER PIC 999V99 VALUE 365. 02 ANT-INNT-PERIODER-PENSJONIST REDEFINES TABELL-INNTPERIODER-PENSJONIST OCCURS 7 TIMES PIC 999V99. * PENSJONIST TABELLER * ANTALL TREKKPERIODER * ANTALL TREKKPERIODER FOR 4, 3, 2 OG 1 DAG BLIR BEREGNET I * A-INITIALISER SECTION. 02 TABELL-TRKPERIODER-PENSJONIST. 05 FILLER PIC 999V9(7) VALUE 11. 05 FILLER PIC 999V9(7) VALUE 24. 05 FILLER PIC 999V9(7) VALUE 48. 05 FILLER PIC 999V9(7) VALUE 0. 05 FILLER PIC 999V9(7) VALUE 0. 05 FILLER PIC 999V9(7) VALUE 0. 05 FILLER PIC 999V9(7) VALUE 0. 02 ANT-TRK-PERIODER-PENSJONIST REDEFINES TABELL-TRKPERIODER-PENSJONIST OCCURS 7 TIMES PIC 999V9(7). * STANDARDFRADRAG-TABELLER * ANTALL INNTEKTSPERIODER 02 TABELL-INNTPERIODER-STFRADRAG. 05 FILLER PIC 999V99 VALUE 12. 05 FILLER PIC 999V99 VALUE 26. 05 FILLER PIC 999V99 VALUE 52. 05 FILLER PIC 999V99 VALUE 91. 05 FILLER PIC 999V99 VALUE 122. 05 FILLER PIC 999V99 VALUE 183. 05 FILLER PIC 999V99 VALUE 365. 02 ANT-INNT-PERIODER-STFRADRAG REDEFINES TABELL-INNTPERIODER-STFRADRAG OCCURS 7 TIMES PIC 999V99. * STANDARDFRADRAG-TABELLER * ANTALL TREKKPERIODER * ANTALL TREKKPERIODER FOR 4, 3, 2 OG 1 DAG BLIR BEREGNET I * A-INITIALISER SECTION. 02 TABELL-TREKKPERIODER-STFRADRAG. 05 FILLER PIC 999V9(7) VALUE 10,5. 05 FILLER PIC 999V9(7) VALUE 23,0. 05 FILLER PIC 999V9(7) VALUE 46,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 05 FILLER PIC 999V9(7) VALUE 0,0. 02 ANT-TRK-PERIODER-STFRADRAG REDEFINES TABELL-TREKKPERIODER-STFRADRAG OCCURS 7 TIMES PIC 999V9(7). Beregning av forskuddstrekk 16

* SJØ-TABELLER * ANTALL INNTEKTSPERIODER 02 TABELL-INNTPERIODER-SJO. 05 FILLER PIC 999V99 VALUE 12. 05 FILLER PIC 999V99 VALUE 26. 05 FILLER PIC 999V99 VALUE 52. 02 ANT-INNT-PERIODER-SJO REDEFINES TABELL-INNTPERIODER-SJO OCCURS 3 TIMES PIC 999V99. * SJØ-TABELLER * ANTALL TREKKPERIODER 02 TABELL-TREKKPERIODER-SJO. 05 FILLER PIC 999V9(7) VALUE 12. 05 FILLER PIC 999V9(7) VALUE 26. 05 FILLER PIC 999V9(7) VALUE 52. 02 ANT-TRK-PERIODER-SJO REDEFINES TABELL-TREKKPERIODER-SJO OCCURS 3 TIMES PIC 999V9(7). * KLASSE-FRADRAG 02 TABELL-KLASSE-FRADRAG. 05 KLASSE1 PIC 9(7). 05 KLASSE2 PIC 9(7). 02 WS-KLASSE-FRADRAG REDEFINES TABELL-KLASSE-FRADRAG OCCURS 2 TIMES PIC 9(7). 02 KLASSE1-VANLIG PIC 9(7) VALUE 48800. 02 KLASSE2-VANLIG PIC 9(7) VALUE 72000. 02 KLASSE1-FINNMARK PIC 9(7) VALUE 63800. 02 KLASSE2-FINNMARK PIC 9(7) VALUE 87000. * TABELL FOR PROSENT PÅ TOPPSKATT 02 TABELL-TOPPSKATT-PROSENT. 05 TRINN1 PIC 99V99. 05 TRINN2 PIC 99V99 VALUE 12,0. 02 TOPPSKATT-PROSENT REDEFINES TABELL-TOPPSKATT-PROSENT OCCURS 2 TIMES PIC 99V99. 02 TOPPSK-TRINN1 PIC 99V9 VALUE 9,0. 02 TOPPSK-TRINN1-FINNMARK PIC 99V9 VALUE 7,0. * TABELL FOR NEDERSTE GRENSE PÅ TOPPSKATT 02 TABELL-TOPPSKATT-LAV-GRENSE. 05 KLASSE1 PIC 9(7) VALUE 527400. 05 KLASSE2 PIC 9(7) VALUE 527400. 02 TOPPSKATT-LAV REDEFINES TABELL-TOPPSKATT-LAV-GRENSE OCCURS 2 TIMES PIC 9(7). Beregning av forskuddstrekk 17

* TABELL FOR ØVERSTE GRENSE PÅ TOPPSKATT 02 TABELL-TOPPSKATT-HOY-GRENSE. 05 KLASSE1 PIC 9(7) VALUE 857300. 05 KLASSE2 PIC 9(7) VALUE 857300. 02 TOPPSKATT-HOY REDEFINES TABELL-TOPPSKATT-HOY-GRENSE OCCURS 2 TIMES PIC 9(7). * HJELPEFELT FOR TABELLNR. 01 WS-TABELL-NUMMER. 05 WS-SKATTE-PROSENT PIC 9. 05 WS-TABELL-TYPE PIC 9. 05 WS-TABELL-NR PIC 99. * HJELPEFELTER FOR PARAMETERVERDIENE 01 WS-PARAMETER-VERDIER. 05 WS-TABELLNR PIC 9(4). 05 WS-PENSJONIST PIC X. 05 WS-TAB-TREKK-PERIODE PIC 9. 05 WS-TREKK-GRLAG PIC 9(7). * KOMMUNE/FYLKE - OG FELLES-SKATT 05 FELLES-SKATT-PROSENT PIC 99V99. 05 FELLES-SKATT-VANLIG PIC 99V99 VALUE 12,95. 05 FELLES-SKATT-FINNMARK PIC 99V99 VALUE 9,45. 05 SKATTORE PIC 99V99 VALUE 14,05. * BEREGNER GRENSER FOR TRYGDEAVGIFTEN. MÅ ENDRES HVIS TRYGDE- * AVGIFTS-PROSENTEN/GRENSEN ENDRES. * FORMEL: *(AARS-INNTEKT - AVG-FRI-TRYGDEAVGIFT) * 0.25 = AARS-INNTEKT * * TRYGDEAVGIFT-PROSENT * DET VIL ALTSÅ SI: * (X - 39600) * 0.25 = X * 0.082(ELLER 0.051 VED LAV) * X = 58929 (VED HØY TRYGDEAVGIFT) * X = 49749 (VED LAV TRYGDEAVGIFT) 05 LAV-GRENSE-TRYGDEAVGIFT PIC 9(6) VALUE 49749. 05 HOY-GRENSE-TRYGDEAVGIFT PIC 9(6) VALUE 58929. 05 TRYGDE-PROSENT PIC 99 VALUE 25. 05 LAV-TRYGDEAVG-PROSENT PIC 99V99 VALUE 5,1. 05 HOY-TRYGDEAVG-PROSENT PIC 99V99 VALUE 8,2. 05 AVG-FRI-TRYGDEAVGIFT PIC 9(6) VALUE 39600. * STANDARDFRADRAG 05 STFRADRAG-PROSENT PIC 99 VALUE 10. 05 MAX-STFRADRAG PIC 9(7) VALUE 40000. Beregning av forskuddstrekk 18

* ANVENDT MINSTEFRADRAG 05 ANV-MINSTE-FRAD-PROSENT PIC 99V99 VALUE 37,84. 05 ANV-MINSTE-FRAD-PROSENT-PENSJ PIC 99V99 VALUE 23,76. 05 MIN-ANV-MINSTE-FRADRAG PIC 9(6) VALUE 3520. 05 MAX-ANV-MINSTE-FRADRAG PIC 9(6) VALUE 74052. 05 MAX-ANV-MINSTE-FRADRAG-PENSJ PIC 9(6) VALUE 61952. * MINSTEFRADRAG 05 MINSTE-FRAD-PROSENT PIC 99V99 VALUE 43,0. 05 MIN-MINSTE-FRADRAG PIC 9(6) VALUE 4000. 05 MAX-MINSTE-FRADRAG PIC 9(6) VALUE 84150. * LØNNSFRADRAG 05 LONNSFRADRAG PIC 9(6) VALUE 31800. 05 ANV-LONNSFRADRAG PIC 9(6) VALUE 27984. * SJØ-FRADRAG 05 SJO-PROSENT PIC 99 VALUE 30. 05 MAX-SJO-FRADRAG PIC 9(7) VALUE 80000. * DIVERSE REGNE- OG HJELPE-FELTER 01 HJELPE-FELTER. 05 AARS-INNTEKT PIC S9(7)V9(9) VALUE 0. 05 KLASSE-FRADRAG PIC S9(7) VALUE 0. 05 FRADRAG PIC S9(7) VALUE 0. 05 SKATTBAR-INNTEKT PIC S9(7)V9(9) VALUE 0. 05 OVERSKYTENDE-TREKK PIC S9(7)V9(9) VALUE 0. 05 OVERSKYTENDE-PROSENT PIC 99V99 VALUE 0. 05 TOPP-SKATT-TRINN1 PIC S9(7)V9(9) VALUE 0. 05 TOPP-SKATT-TRINN2 PIC S9(7)V9(9) VALUE 0. 05 SUM-TOPP-SKATT PIC S9(7)V9(9) VALUE 0. 05 MAX-TREKK-GRUNNLAG PIC S9(7) VALUE 0. 05 ANT-INNTEKTS-PERIODER PIC S9(3)V99 VALUE 0. 05 ANT-TREKK-PERIODER PIC S9(3)V9(7) VALUE 0. 05 SUM-TREKK PIC S9(7)V9(9) VALUE 0. 05 TREKK PIC S9(7) VALUE 0. 05 KOMMUNE-SKATT PIC S9(7)V9(9) VALUE 0. 05 FELLES-SKATT PIC S9(7)V9(9) VALUE 0. 05 TRYGDE-AVGIFT PIC S9(7)V9(9) VALUE 0. 05 ST-FRADRAG PIC 9(7)V9(9) VALUE 0. 05 ANV-MINSTE-FRADRAG PIC S9(6)V9(9) VALUE 0. 05 MINSTE-FRADRAG PIC S9(6)V9(9) VALUE 0. 05 SJO-FRADRAG PIC 9(7) VALUE 0. 05 WS-TRGRL-AVRUNDET PIC 9(7). 05 WS-LONNSFRADRAG PIC 9(6). Beregning av forskuddstrekk 19

LINKAGE SECTION. 77 PARM-TABELLNR PIC 9(4). 77 PARM-PENSJONIST PIC X. 77 PARM-TAB-TREKK-PERIODE PIC 9. 77 PARM-TREKK-GRLAG PIC 9(7). 77 PARM-UT-TREKK PIC 9(7). PROCEDURE DIVISION USING PARM-TABELLNR PARM-PENSJONIST PARM-TAB-TREKK-PERIODE PARM-TREKK-GRLAG PARM-UT-TREKK. HOVED SECTION. PERFORM A-INITIALISER PERFORM A-STYRE GOBACK. A-INITIALISER SECTION. MOVE PARM-TABELLNR TO WS-TABELL-NUMMER WS-TABELLNR MOVE PARM-PENSJONIST TO WS-PENSJONIST MOVE PARM-TAB-TREKK-PERIODE TO WS-TAB-TREKK-PERIODE MOVE PARM-TREKK-GRLAG TO WS-TREKK-GRLAG INITIALIZE HJELPE-FELTER * VANLIGE TABELLER * BEREGNING AV ANTALL TREKKPERIODER FOR 4, 3, 2 OG 1 DAG COMPUTE ANT-TRK-PERIODER-VANLIG(4) ROUNDED = (60 * 46) / 52 COMPUTE ANT-TRK-PERIODER-VANLIG(5) ROUNDED = (80 * 46) / 52 COMPUTE ANT-TRK-PERIODER-VANLIG(6) ROUNDED = (120 * 46) / 52 COMPUTE ANT-TRK-PERIODER-VANLIG(7) ROUNDED = (240 * 46) / 52 * PENSJONIST-TABELLER * BEREGNING AV ANTALL TREKKPERIODER FOR 4, 3, 2 OG 1 DAG COMPUTE ANT-TRK-PERIODER-PENSJONIST(4) ROUNDED = (91 * 11) / 12 COMPUTE ANT-TRK-PERIODER-PENSJONIST(5) ROUNDED = (122 * 11) / 12 COMPUTE ANT-TRK-PERIODER-PENSJONIST(6) ROUNDED = (183 * 11) / 12 COMPUTE ANT-TRK-PERIODER-PENSJONIST(7) ROUNDED = (365 * 11) / 12 Beregning av forskuddstrekk 20

* STANDARD-FRADRAG TABELLER * BEREGNING AV ANTALL TREKKPERIODER FOR 4, 3, 2 OG 1 DAG COMPUTE ANT-TRK-PERIODER-STFRADRAG(4) ROUNDED = (91 * 10,5) / 12 COMPUTE ANT-TRK-PERIODER-STFRADRAG(5) ROUNDED = (122 * 10,5) / 12 COMPUTE ANT-TRK-PERIODER-STFRADRAG(6) ROUNDED = (183 * 10,5) / 12 COMPUTE ANT-TRK-PERIODER-STFRADRAG(7) ROUNDED = (365 * 10,5) / 12 * OM DET ER EN VANLIG TABELL (7100-7200) ELLER * PENSJONIST-TABELL (7100P-7200P) ELLER * STANDARD-FRADRAG TABELL (7300-7800) IF WS-TABELL-TYPE < 3 MOVE 1 TO TABELLTYPE ELSE MOVE 3 TO TABELLTYPE IF WS-PENSJONIST = 'P' MOVE 2 TO TABELLTYPE IF WS-SKATTE-PROSENT = 0 MOVE 4 TO TABELLTYPE * SETTER SATSER/GRENSER FOR DE SPESIELLE STANDARDFRADRAG- * TABELLENE FOR FINNMARK IF WS-SKATTE-PROSENT = 6 MOVE TOPPSK-TRINN1-FINNMARK TO TOPPSKATT-PROSENT(1) MOVE KLASSE1-FINNMARK TO WS-KLASSE-FRADRAG(1) MOVE KLASSE2-FINNMARK TO WS-KLASSE-FRADRAG(2) MOVE FELLES-SKATT-FINNMARK TO FELLES-SKATT-PROSENT ELSE MOVE TOPPSK-TRINN1 TO TOPPSKATT-PROSENT(1) MOVE KLASSE1-VANLIG TO WS-KLASSE-FRADRAG(1) MOVE KLASSE2-VANLIG TO WS-KLASSE-FRADRAG(2) MOVE FELLES-SKATT-VANLIG TO FELLES-SKATT-PROSENT Beregning av forskuddstrekk 21

* FOR HVILKEN PERIODE DET SKAL BEREGNES FORSKUDDSTREKK * WS-TAB-TREKK-PERIODE = 1 (MÅNEDSTABELL) * WS-TAB-TREKK-PERIODE = 2 (14 DAGER) * WS-TAB-TREKK-PERIODE = 3 (1 UKE) * WS-TAB-TREKK-PERIODE = 4 (4 DAGER) * WS-TAB-TREKK-PERIODE = 5 (3 DAGER) * WS-TAB-TREKK-PERIODE = 6 (2 DAGER) * WS-TAB-TREKK-PERIODE = 7 (1 DAGER) EVALUATE WS-TAB-TREKK-PERIODE WHEN 1 MOVE 1 TO TAB-TREKK-PERIODE WHEN 2 MOVE 2 TO TAB-TREKK-PERIODE WHEN 3 MOVE 3 TO TAB-TREKK-PERIODE WHEN 4 MOVE 4 TO TAB-TREKK-PERIODE WHEN 5 MOVE 5 TO TAB-TREKK-PERIODE WHEN 6 MOVE 6 TO TAB-TREKK-PERIODE WHEN 7 MOVE 7 TO TAB-TREKK-PERIODE END-EVALUATE. A-STYRE SECTION. EVALUATE TRUE WHEN VANLIG PERFORM B-SETT-VERDIER-VANLIG WHEN PENSJONIST PERFORM B-SETT-VERDIER-PENSJONIST WHEN STANDARD-FRADRAG PERFORM B-SETT-VERDIER-STFRADRAG WHEN SJO PERFORM B-SETT-VERDIER-SJO END-EVALUATE PERFORM B-AVRUNDING PERFORM B-BEREGN-FRADRAG PERFORM B-BEREGN-NETTOSKATT PERFORM B-BEREGN-TRYGDEAVGIFT PERFORM B-BEREGN-TOPPSKATT PERFORM B-BEREGN-TREKK. Beregning av forskuddstrekk 22

*************************************** 7100-7260 ************** B-SETT-VERDIER-VANLIG SECTION. MOVE WS-TABELL-TYPE TO KLASSE MOVE MAX-TRK-GRLAG (WS-TAB-TREKK-PERIODE) TO MAX-TREKK-GRUNNLAG IF WS-TABELL-NR = 50 OR 60 OR 70 MOVE ANT-INNT-PERIODER-STFRADRAG (WS-TAB-TREKK-PERIODE) TO ANT-INNTEKTS-PERIODER ELSE MOVE ANT-INNT-PERIODER-VANLIG (WS-TAB-TREKK-PERIODE) TO ANT-INNTEKTS-PERIODER IF WS-TABELL-NR = 50 OR 60 MOVE ANT-INNT-PERIODER-STFRADRAG (WS-TAB-TREKK-PERIODE) TO ANT-TREKK-PERIODER ELSE IF WS-TABELL-NR = 70 MOVE ANT-TRK-PERIODER-STFRADRAG (WS-TAB-TREKK-PERIODE) TO ANT-TREKK-PERIODER ELSE MOVE ANT-TRK-PERIODER-VANLIG (WS-TAB-TREKK-PERIODE) TO ANT-TREKK-PERIODER IF WS-TREKK-GRLAG > MAX-TREKK-GRUNNLAG PERFORM B-BEREGN-OVERSKYTENDE-TREKK. *************************************** P-TABELLER *************** B-SETT-VERDIER-PENSJONIST SECTION. MOVE WS-TABELL-TYPE TO KLASSE MOVE MAX-TRK-GRLAG (WS-TAB-TREKK-PERIODE) TO MAX-TREKK-GRUNNLAG MOVE ANT-INNT-PERIODER-PENSJONIST (WS-TAB-TREKK-PERIODE) TO ANT-INNTEKTS-PERIODER MOVE ANT-TRK-PERIODER-PENSJONIST (WS-TAB-TREKK-PERIODE) TO ANT-TREKK-PERIODER IF WS-TREKK-GRLAG > MAX-TREKK-GRUNNLAG PERFORM B-BEREGN-OVERSKYTENDE-TREKK. Beregning av forskuddstrekk 23

*************************************** 7300-7800 ************** B-SETT-VERDIER-STFRADRAG SECTION. IF WS-TABELL-TYPE = 3 OR 5 OR 7 MOVE 1 TO KLASSE ELSE MOVE 2 TO KLASSE MOVE MAX-TRK-GRLAG (WS-TAB-TREKK-PERIODE) TO MAX-TREKK-GRUNNLAG MOVE ANT-INNT-PERIODER-STFRADRAG (WS-TAB-TREKK-PERIODE) TO ANT-INNTEKTS-PERIODER IF WS-TABELLNR = 7350 OR 7450 OR 7500 OR 7600 OR 7700 OR 7800 OR 6350 OR 6450 OR 6500 OR 6600 OR 6700 OR 6800 MOVE ANT-INNT-PERIODER-STFRADRAG (WS-TAB-TREKK-PERIODE) TO ANT-TREKK-PERIODER ELSE MOVE ANT-TRK-PERIODER-STFRADRAG (WS-TAB-TREKK-PERIODE) TO ANT-TREKK-PERIODER IF WS-TREKK-GRLAG > MAX-TREKK-GRUNNLAG PERFORM B-BEREGN-OVERSKYTENDE-TREKK. *************************************** 0100-0201 ************** B-SETT-VERDIER-SJO SECTION. IF WS-TABELL-TYPE = 1 MOVE 1 TO KLASSE ELSE MOVE 2 TO KLASSE MOVE MAX-TRK-GRLAG (WS-TAB-TREKK-PERIODE) TO MAX-TREKK-GRUNNLAG MOVE ANT-INNT-PERIODER-SJO (WS-TAB-TREKK-PERIODE) TO ANT-INNTEKTS-PERIODER MOVE ANT-TRK-PERIODER-SJO (WS-TAB-TREKK-PERIODE) TO ANT-TREKK-PERIODER IF WS-TREKK-GRLAG > MAX-TREKK-GRUNNLAG PERFORM B-BEREGN-OVERSKYTENDE-TREKK. Beregning av forskuddstrekk 24

B-AVRUNDING SECTION. * SAMTLIGE TABELLER * AVRUNDER TREKKGRUNNLAGET UT I FRA PERIODEN DET SKAL BEREGNES * TREKK FOR. EVALUATE TRUE WHEN MAANED COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG / 100 COMPUTE WS-TRGRL-AVRUNDET = WS-TREKK-GRLAG * 100 COMPUTE WS-TREKK-GRLAG = (WS-TREKK-GRLAG * 100) + 50 WHEN 14-DAGER COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG / 50 COMPUTE WS-TRGRL-AVRUNDET = WS-TREKK-GRLAG * 50 COMPUTE WS-TREKK-GRLAG = (WS-TREKK-GRLAG * 50) + 25 WHEN OTHER COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG / 20 COMPUTE WS-TRGRL-AVRUNDET = WS-TREKK-GRLAG * 20 COMPUTE WS-TREKK-GRLAG = (WS-TREKK-GRLAG * 20) + 10 END-EVALUATE COMPUTE AARS-INNTEKT = WS-TREKK-GRLAG * ANT-INNTEKTS-PERIODER. Beregning av forskuddstrekk 25

B-BEREGN-OVERSKYTENDE-TREKK SECTION. * FORSKUDDSTREKK AV DEN DEL AV TREKKGRUNNLAGET SOM OVERSTIGER * MAX TREKKGRUNNLAG I DEN AKTUELLE TABELLEN. * DET SETTES EN GITT PROSENT-SATS FOR DET BELØPET SOM DET SKAL * BEREGNES TREKK AV 'UTENFOR' TABELLEN, AVHENGIG AV TABELL-NUMMER. EVALUATE TRUE WHEN PENSJONIST MOVE 0,48 TO OVERSKYTENDE-PROSENT WHEN VANLIG MOVE 0,54 TO OVERSKYTENDE-PROSENT END-EVALUATE IF WS-TABELLNR = 7300 OR 7400 MOVE 0,54 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 7350 OR 7450 MOVE 0,47 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 7500 OR 7600 MOVE 0,39 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 7550 OR 7650 MOVE 0,45 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 7700 OR 7800 MOVE 0,44 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 0100 OR 0200 MOVE 0,39 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 0101 OR 0201 MOVE 0,47 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 6300 OR 6400 MOVE 0,50 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 6350 OR 6450 MOVE 0,44 TO OVERSKYTENDE-PROSENT Beregning av forskuddstrekk 26

IF WS-TABELLNR = 6500 OR 6600 MOVE 0,36 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 6550 OR 6650 MOVE 0,41 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 6700 OR 6800 MOVE 0,41 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 7150 OR 7250 MOVE 0,47 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 7160 OR 7260 MOVE 0,39 TO OVERSKYTENDE-PROSENT IF WS-TABELLNR = 7170 OR 7270 MOVE 0,45 TO OVERSKYTENDE-PROSENT Beregning av forskuddstrekk 27

* BEREGNER DET OVERSKYTENDE TREKKET * (ETTER FØRST Å HA RUNDET DET AV) EVALUATE TRUE WHEN MAANED COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG / 100 COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG * 100 WHEN 14-DAGER COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG / 50 COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG * 50 WHEN UKE OR 4-DAGER OR 3-DAGER OR 2-DAGER OR 1-DAG COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG / 20 COMPUTE WS-TREKK-GRLAG = WS-TREKK-GRLAG * 20 END-EVALUATE COMPUTE OVERSKYTENDE-TREKK = (WS-TREKK-GRLAG - MAX-TREKK-GRUNNLAG) * OVERSKYTENDE-PROSENT * SETTER WS-TREKK-GRLAG LIK MAX-TREKK-GRLAG FORDI DET IKKE * SKAL BEREGNES SKATT AV DEN OVERSKYTENDE DELEN AV GRUNNLAGET MOVE MAX-TREKK-GRUNNLAG TO WS-TREKK-GRLAG. Beregning av forskuddstrekk 28

B-BEREGN-FRADRAG SECTION. * BEREGNER MINSTEFRADRAG * FOR VANLIG OG STANDARD-FRADRAG TABELLER * HER BRUKES ANVENDT MINSTEFRADRAG EVALUATE TRUE WHEN VANLIG OR STANDARD-FRADRAG COMPUTE ANV-MINSTE-FRADRAG = (AARS-INNTEKT * ANV-MINSTE-FRAD-PROSENT) / 100 IF ANV-MINSTE-FRADRAG > MAX-ANV-MINSTE-FRADRAG MOVE MAX-ANV-MINSTE-FRADRAG TO ANV-MINSTE-FRADRAG ELSE IF ANV-MINSTE-FRADRAG < MIN-ANV-MINSTE-FRADRAG MOVE MIN-ANV-MINSTE-FRADRAG TO ANV-MINSTE-FRADRAG IF AARS-INNTEKT < ANV-LONNSFRADRAG MOVE AARS-INNTEKT TO WS-LONNSFRADRAG ELSE MOVE ANV-LONNSFRADRAG TO WS-LONNSFRADRAG IF WS-LONNSFRADRAG < 0 MOVE 0 TO WS-LONNSFRADRAG IF WS-LONNSFRADRAG > ANV-MINSTE-FRADRAG MOVE WS-LONNSFRADRAG TO ANV-MINSTE-FRADRAG IF AARS-INNTEKT < ANV-MINSTE-FRADRAG MOVE AARS-INNTEKT TO ANV-MINSTE-FRADRAG END-EVALUATE * BEREGNER MINSTEFRADRAG * FOR PENSJONIST- TABELLER * HER BRUKES ANVENDT MINSTEFRADRAG EVALUATE TRUE WHEN PENSJONIST COMPUTE ANV-MINSTE-FRADRAG = (AARS-INNTEKT * ANV-MINSTE-FRAD-PROSENT-PENSJ) / 100 IF ANV-MINSTE-FRADRAG > MAX-ANV-MINSTE-FRADRAG-PENSJ MOVE MAX-ANV-MINSTE-FRADRAG-PENSJ TO ANV-MINSTE-FRADRAG ELSE IF ANV-MINSTE-FRADRAG < MIN-ANV-MINSTE-FRADRAG MOVE MIN-ANV-MINSTE-FRADRAG TO ANV-MINSTE-FRADRAG END-EVALUATE Beregning av forskuddstrekk 29

* BEREGNER MINSTEFRADRAG * FOR SJØ-TABELLER * HER BRUKES REELT MINSTEFRADRAG EVALUATE TRUE WHEN SJO COMPUTE MINSTE-FRADRAG = (AARS-INNTEKT * MINSTE-FRAD-PROSENT) / 100 IF MINSTE-FRADRAG > MAX-MINSTE-FRADRAG MOVE MAX-MINSTE-FRADRAG TO MINSTE-FRADRAG ELSE IF MINSTE-FRADRAG < MIN-MINSTE-FRADRAG MOVE MIN-MINSTE-FRADRAG TO MINSTE-FRADRAG IF AARS-INNTEKT < LONNSFRADRAG MOVE AARS-INNTEKT TO WS-LONNSFRADRAG ELSE MOVE LONNSFRADRAG TO WS-LONNSFRADRAG IF WS-LONNSFRADRAG < 0 MOVE 0 TO WS-LONNSFRADRAG IF WS-LONNSFRADRAG > MINSTE-FRADRAG MOVE WS-LONNSFRADRAG TO MINSTE-FRADRAG IF AARS-INNTEKT < MINSTE-FRADRAG MOVE AARS-INNTEKT TO MINSTE-FRADRAG END-EVALUATE * BEREGNER DET FRADRAG/TILLEGG I INNTEKTEN MAN SKAL TA HENSYN * TIL VED BEREGNING AV FORSKUDDSTREKK. * DETTE BEREGNES BARE FOR VANLIGE OG PENSJONIST-TABELLER. * STANDARDFRADRAG- OG SJØ-TABELLENE HAR IKKE SLIKT FRADRAG. EVALUATE TRUE ALSO TRUE WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR < 10 COMPUTE FRADRAG = WS-TABELL-NR * 4000 WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 10 MOVE 41000 TO FRADRAG WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 11 MOVE 46000 TO FRADRAG WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 12 MOVE 53000 TO FRADRAG WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR > 12 AND WS-TABELL-NR < 20 COMPUTE FRADRAG = (WS-TABELL-NR - 7) * 10000 WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR > 19 AND WS-TABELL-NR < 29 COMPUTE FRADRAG = - (WS-TABELL-NR - 19) * 4000 WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 29 MOVE -41000 TO FRADRAG WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 30 MOVE -46000 TO FRADRAG Beregning av forskuddstrekk 30

WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 31 MOVE -53000 TO FRADRAG WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 32 MOVE -60000 TO FRADRAG WHEN VANLIG OR PENSJONIST ALSO WS-TABELL-NR = 33 MOVE -67000 TO FRADRAG END-EVALUATE * BEREGNER STANDARDFRADRAG EVALUATE TRUE WHEN STANDARD-FRADRAG OR SJO COMPUTE ST-FRADRAG = (AARS-INNTEKT * STFRADRAG-PROSENT) / 100 END-EVALUATE IF ST-FRADRAG > MAX-STFRADRAG MOVE MAX-STFRADRAG TO ST-FRADRAG * BEREGNER SJOMANNS-FRADRAG EVALUATE TRUE WHEN SJO COMPUTE SJO-FRADRAG = (AARS-INNTEKT * SJO-PROSENT) / 100 END-EVALUATE IF SJO-FRADRAG > MAX-SJO-FRADRAG MOVE MAX-SJO-FRADRAG TO SJO-FRADRAG * BEREGNER KLASSEFRADRAG COMPUTE KLASSE-FRADRAG = WS-KLASSE-FRADRAG(KLASSE) * BEREGNER DEN DEL AV INNTEKTEN DET SKAL TREKKES SKATT AV COMPUTE SKATTBAR-INNTEKT = AARS-INNTEKT - ANV-MINSTE-FRADRAG - MINSTE-FRADRAG - FRADRAG - ST-FRADRAG - SJO-FRADRAG - KLASSE-FRADRAG. B-BEREGN-NETTOSKATT SECTION. * HVIS SKATTBAR-INNTEKT ER NEGATIV, SKAL DET IKKE BEREGNES * KOMMUNE- OG FELLES-SKATT. IF SKATTBAR-INNTEKT NEGATIVE GO TO B-BEREGN-NETTOSKATT-SLUTT Beregning av forskuddstrekk 31

* BEREGNER KOMMUNESKATT COMPUTE KOMMUNE-SKATT = (SKATTBAR-INNTEKT * SKATTORE) / 100 * BEREGNER FELLESSKATT COMPUTE FELLES-SKATT = (SKATTBAR-INNTEKT * FELLES-SKATT-PROSENT) / 100. B-BEREGN-NETTOSKATT-SLUTT. EXIT. B-BEREGN-TRYGDEAVGIFT SECTION. * LUKER UT DE FOREKOMSTENE HVOR DET IKKE SKAL BETALES TRYGDEAVGIFT IF WS-TABELLNR = 7500 OR 7550 OR 7600 OR 7650 OR 0100 OR 0200 OR 6500 OR 6550 OR 6600 OR 6650 OR 7160 OR 7170 OR 7260 OR 7270 OR AARS-INNTEKT < AVG-FRI-TRYGDEAVGIFT GO TO B-BEREGN-TRYGDEAVGIFT-SLUTT * BEREGNER DE MED LAV FOLKETRYGD IF WS-TABELLNR = 7700 OR 7800 OR 6700 OR 6800 OR PENSJONIST IF AARS-INNTEKT > LAV-GRENSE-TRYGDEAVGIFT COMPUTE TRYGDE-AVGIFT = (AARS-INNTEKT * LAV-TRYGDEAVG-PROSENT) / 100 ELSE COMPUTE TRYGDE-AVGIFT = (AARS-INNTEKT - AVG-FRI-TRYGDEAVGIFT) * TRYGDE-PROSENT / 100 ELSE * BEREGNER DE MED HØY FOLKETRYGD IF AARS-INNTEKT > HOY-GRENSE-TRYGDEAVGIFT COMPUTE TRYGDE-AVGIFT = (AARS-INNTEKT * HOY-TRYGDEAVG-PROSENT) / 100 ELSE COMPUTE TRYGDE-AVGIFT = (AARS-INNTEKT - AVG-FRI-TRYGDEAVGIFT) * TRYGDE-PROSENT / 100. B-BEREGN-TRYGDEAVGIFT-SLUTT. EXIT. Beregning av forskuddstrekk 32

B-BEREGN-TOPPSKATT SECTION. IF AARS-INNTEKT > TOPPSKATT-LAV(KLASSE) IF AARS-INNTEKT < TOPPSKATT-HOY(KLASSE) COMPUTE TOPP-SKATT-TRINN1 = (AARS-INNTEKT - TOPPSKATT-LAV(KLASSE)) * TOPPSKATT-PROSENT(1) / 100 ELSE COMPUTE TOPP-SKATT-TRINN1 = (TOPPSKATT-HOY(KLASSE) - TOPPSKATT-LAV(KLASSE)) * TOPPSKATT-PROSENT(1) / 100 IF AARS-INNTEKT > TOPPSKATT-HOY(KLASSE) COMPUTE TOPP-SKATT-TRINN2 = (AARS-INNTEKT - TOPPSKATT-HOY(KLASSE)) * TOPPSKATT-PROSENT(2) / 100 COMPUTE SUM-TOPP-SKATT = TOPP-SKATT-TRINN1 + TOPP-SKATT-TRINN2. B-BEREGN-TREKK SECTION. COMPUTE SUM-TREKK = KOMMUNE-SKATT + FELLES-SKATT + TRYGDE-AVGIFT + SUM-TOPP-SKATT IF SJO COMPUTE TREKK = (SUM-TREKK / ANT-TREKK-PERIODER) ELSE COMPUTE TREKK ROUNDED = (SUM-TREKK / ANT-TREKK-PERIODER) IF TREKK NEGATIVE MOVE 0 TO TREKK IF TREKK > WS-TRGRL-AVRUNDET MOVE WS-TRGRL-AVRUNDET TO TREKK COMPUTE TREKK = TREKK + OVERSKYTENDE-TREKK MOVE TREKK TO PARM-UT-TREKK. Beregning av forskuddstrekk 33